' @(f)
'
' 機能      : テーブル リンク
'
' 引き数    : ARG1 - Databaseオブジェクト
'             ARG2 - ソーステーブル名
'             ARG3 - リンク元D/B名
'             ARG4 - リンク元D/Bパスワード ... 省略可
'             ARG5 - テーブル名 ... 省略可(省略時 ARG2)
'
' 機能説明  : ARG3(Database)の ARG2テーブルを ARG1(Database)にリンクする
'
' 備考      :
'
Public Sub pLinkTable(db As Database, _
                      ByVal strSourceTableName As String, _
                      ByVal strOriginalDbName As String, _
                      Optional ByVal vPassword As Variant, _
                      Optional ByVal strTableName As String = "")
    Dim strConnect  As String
    Dim td          As TableDef
    
    strConnect = ";DATABASE=" & strOriginalDbName
    If Not IsMissing(vPassword) Then
        strConnect = strConnect & ";PWD=" & vPassword
    End If
    
    If strTableName = "" Then strTableName = strSourceTableName
    
    For Each td In db.TableDefs
        '' Table Exist
        If UCase(td.Name) = UCase(strTableName) Then
            If UCase(td.SourceTableName) <> UCase(strSourceTableName) Then
                db.TableDefs.Delete strTableName
                db.TableDefs.Refresh
                Exit For
            End If
            If UCase(td.Connect) <> UCase(strConnect) Then
                td.Connect = strConnect
                td.RefreshLink
            End If
            Exit Sub
        End If
    Next td
    
    '' Link Table Create
    Set td = db.CreateTableDef(strTableName)
    With td
        .SourceTableName = strSourceTableName
        .Connect = strConnect
    End With
    db.TableDefs.Append td
    db.TableDefs.Refresh
    
    Set td = Nothing
End Sub